kc3-lang/gnulib/m4/getpass.m4

• Show log

  Commit

• Hash : 42d1eda5
  Author :
  Date : 2009-01-13T08:48:48
  

  many *.m4 files: improve m4 quoting
  
  99% of this change was performed by running the following commands:
  git ls-files | grep '\.m4$' | xargs perl -pi \
    -e 's/(AC_\w+\()([^[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){1})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){2})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){3})([^,[()]+?)([,)])/$1\[$2]$3/g'
  perl -pi -e 's/\[\.\.\.\]/.../' m4/onceonly.m4
  
  The remainder were to add Copyright dates, increment serial numbers,
  undo some changes in comments, exclude m4/intl.m4, and add quotes
  around the "1" in ",1" where the unusual spacing prohibited the
  above regexps from doing the job.  For more details, see
  <http://thread.gmane.org/gmane.comp.lib.gnulib.bugs/16175>.
  

Download

• m4/getpass.m4

• # getpass.m4 serial 11
  dnl Copyright (C) 2002-2003, 2005-2006, 2009 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  # Provide a getpass() function if the system doesn't have it.
  AC_DEFUN([gl_FUNC_GETPASS],
  [
    AC_REPLACE_FUNCS([getpass])
    AC_CHECK_DECLS_ONCE([getpass])
    if test $ac_cv_func_getpass = no; then
      gl_PREREQ_GETPASS
    fi
  ])
  
  # Provide the GNU getpass() implementation. It supports passwords of
  # arbitrary length (not just 8 bytes as on HP-UX).
  AC_DEFUN([gl_FUNC_GETPASS_GNU],
  [
    AC_CHECK_DECLS_ONCE([getpass])
    dnl TODO: Detect when GNU getpass() is already found in glibc.
    AC_LIBOBJ([getpass])
    gl_PREREQ_GETPASS
    dnl We must choose a different name for our function, since on ELF systems
    dnl an unusable getpass() in libc.so would override our getpass() if it is
    dnl compiled into a shared library.
    AC_DEFINE([getpass], [gnu_getpass],
      [Define to a replacement function name for getpass().])
  ])
  
  # Prerequisites of lib/getpass.c.
  AC_DEFUN([gl_PREREQ_GETPASS], [
    AC_CHECK_HEADERS_ONCE([stdio_ext.h termios.h])
    AC_CHECK_FUNCS_ONCE([__fsetlocking tcgetattr tcsetattr])
    AC_CHECK_DECLS([__fsetlocking],,,
      [#include <stdio.h>
       #if HAVE_STDIO_EXT_H
        #include <stdio_ext.h>
       #endif])
    AC_CHECK_DECLS_ONCE([fflush_unlocked])
    AC_CHECK_DECLS_ONCE([flockfile])
    AC_CHECK_DECLS_ONCE([fputs_unlocked])
    AC_CHECK_DECLS_ONCE([funlockfile])
    AC_CHECK_DECLS_ONCE([putc_unlocked])
    :
  ])
  

Download