kc3-lang/gnulib/m4/inet_ntop.m4

• Show log

  Commit

• Hash : 592f5b54
  Author :
  Date : 2009-04-03T13:24:11
  

  Port inet_ntop to Solaris 8 (problem found in coreutils 7.2).
  
  * modules/arpa_inet (arpa/inet.h): Depend on arpa_inet.in.h.
  * m4/inet_ntop.m4 (gl_INET_NTOP): Search for inet_ntop in -lnsl,
  for Solaris 8.  This is a bit of a hack, as it means it's the
  caller's responsibility to add -lnsl if needed, but most likely it
  won't be needed since only getaddrinfo uses this and getaddrinfo
  isn't needed on Solaris 8.
  

Download

• m4/inet_ntop.m4

• # inet_ntop.m4 serial 9
  dnl Copyright (C) 2005, 2006, 2008, 2009 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_INET_NTOP],
  [
    dnl Persuade Solaris <arpa/inet.h> to declare inet_ntop.
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  
    gl_REPLACE_ARPA_INET_H
  
    dnl The AC_SEARCH_LIBS call is a hack to persuade the Solaris 8 linker to
    dnl find inet_ntop.
    dnl
    dnl It is the responsibility of gl_INET_NTOP's caller to arrange for
    dnl -lnsl if it is needed.  Normally -lnsl is not needed on Solaris 8,
    dnl since inet_ntop is needed only by getaddrinfo, and getaddrinfo
    dnl isn't built on Solaris 8.
    gl_save_LIBS=$LIBS
    AC_SEARCH_LIBS([inet_ntop], [nsl], [],
      [AC_REPLACE_FUNCS([inet_ntop])])
    LIBS=$gl_save_LIBS
  
    gl_PREREQ_INET_NTOP
  ])
  
  # Prerequisites of lib/inet_ntop.c.
  AC_DEFUN([gl_PREREQ_INET_NTOP], [
    AC_CHECK_DECLS([inet_ntop],,,[#include <arpa/inet.h>])
    if test $ac_cv_have_decl_inet_ntop = no; then
      HAVE_DECL_INET_NTOP=0
    fi
    AC_REQUIRE([gl_SOCKET_FAMILIES])
    AC_REQUIRE([AC_C_RESTRICT])
  ])
  

Download