kc3-lang/gnulib/m4/fdopendir.m4

• Show log

  Commit

• Hash : dfbec8be
  Author :
  Date : 2009-10-06T06:58:08
  

  fdopendir: fix GNU/Hurd bug
  
  fdopendir(open("file",O_RDONLY)) mistakenly succeeded, with
  subsequent readdir() failing with ENOTDIR.
  
  * m4/fdopendir.m4 (gl_FUNC_FDOPENDIR): Check for Hurd bug in
  allowing non-directory fds.
  * lib/fdopendir.c (rpl_fdopendir): Work around it.
  * m4/dirent_h.m4 (gl_DIRENT_H_DEFAULTS): New witness.
  * modules/dirent (Makefile.am): Substitute it.
  * lib/dirent.in.h (fdopendir): Declare replacement.
  * doc/posix-functions/fdopendir.texi (fdopendir): Document this.
  * tests/test-fdopendir.c (main): Test something other than
  /dev/null, since on Hurd that behaves like a directory.
  
  Signed-off-by: Eric Blake <ebb9@byu.net>
  

Download

• m4/fdopendir.m4

• # serial 2
  # See if we need to provide fdopendir.
  
  dnl Copyright (C) 2009 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  # Written by Eric Blake.
  
  AC_DEFUN([gl_FUNC_FDOPENDIR],
  [
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
    AC_CHECK_FUNCS_ONCE([fdopendir])
    if test $ac_cv_func_fdopendir = no; then
      AC_LIBOBJ([openat-proc])
      AC_LIBOBJ([fdopendir])
      gl_REPLACE_DIRENT_H
      HAVE_FDOPENDIR=0
    else
      AC_CACHE_CHECK([whether fdopendir works],
        [gl_cv_func_fdopendir_works],
        [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  #include <dirent.h>
  #include <fcntl.h>
  ]], [int fd = open ("conftest.h", O_RDONLY);
       if (fd < 0) return 2;
       return !!fdopendir (fd);])],
  	 [gl_cv_func_fdopendir_works=yes],
  	 [gl_cv_func_fdopendir_works=no],
  	 [gl_cv_func_fdopendir_works="guessing no"])])
      if test "$gl_cv_func_fdopendir_works" != yes; then
        REPLACE_FDOPENDIR=1
        gl_REPLACE_DIRENT_H
        AC_LIBOBJ([fdopendir])
      fi
    fi
  ])
  

Download