kc3-lang/gnulib/m4/remove.m4

• Show log

  Commit

• Hash : 6ca71ffe
  Author :
  Date : 2009-09-14T16:57:55
  

  remove: new module, for mingw and Solaris 9 bugs
  
  Mingw obeys C89, but not POSIX, by not handling directories.
  Solaris remove("file/") mistakenly succeeded.
  
  * modules/remove: New file.
  * lib/remove.c: Likewise.
  * m4/remove.m4 (gl_FUNC_REMOVE): Likewise.
  * m4/stdio_h.m4 (gl_STDIO_H_DEFAULTS): Add witnesses.
  * modules/stdio (Makefile.am): Use them.
  * lib/stdio.in.h (remove): Declare replacement.
  * MODULES.html.sh (systems lacking POSIX:2008): Mention module.
  * doc/posix-functions/remove.texi (remove): Likewise.
  * modules/remove-tests: New test.
  * tests/test-remove.c: Likewise.
  
  Signed-off-by: Eric Blake <ebb9@byu.net>
  

Download

• m4/remove.m4

• # remove.m4 serial 1
  dnl Copyright (C) 2009 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_REMOVE],
  [
    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
    AC_REQUIRE([gl_AC_DOS])
    AC_REQUIRE([gl_STDIO_H_DEFAULTS])
    AC_REQUIRE([gl_FUNC_RMDIR])
    AC_REQUIRE([gl_FUNC_UNLINK])
    if test "$gl_cv_func_rmdir_works:$gl_cv_func_unlink_works" != yes:yes; then
      dnl If either underlying syscall is broken, then remove likely has
      dnl the same bug; blindly use our replacement.
      REPLACE_REMOVE=1
      AC_LIBOBJ([remove])
    else
      dnl C89 requires remove(), but only POSIX requires it to handle
      dnl directories.  On mingw, directories fails with EPERM.
      AC_CACHE_CHECK([whether remove handles directories],
        [gl_cv_func_remove_dir_works],
        [mkdir conftest.dir
         AC_RUN_IFELSE(
           [AC_LANG_PROGRAM(
             [[#include <stdio.h>
  ]], [[return remove ("conftest.dir");]])],
           [gl_cv_func_remove_dir_works=yes], [gl_cv_func_remove_dir_works=no],
           [case $host_os in
              mingw*) gl_cv_func_remove_dir_works="guessing no";;
              *) gl_cv_func_remove_dir_works="guessing yes";;
            esac])
         rm -rf conftest.dir])
      case $gl_cv_func_remove_dir_works in
        *no*) REPLACE_REMOVE=1
          AC_LIBOBJ([remove]);;
      esac
    fi
  ])
  

Download