remainderl.m4

Branch

Show log
Commit

Hash : a923e066
Author :
Date : 2025-09-10T22:55:08

math-h: Remove support for IRIX.

* lib/math.in.h (FP_ILOGB0, FP_ILOGBNAN): Remove code for IRIX.
(cbrtf): Test HAVE_CBRTF instead of HAVE_DECL_CBRTF.
(cbrtl): Test HAVE_CBRTL instead of HAVE_DECL_CBRTL.
(copysignf): Test HAVE_COPYSIGNF instead of HAVE_DECL_COPYSIGNF.
(exp2f): Test HAVE_EXP2F instead of HAVE_DECL_EXP2F.
(exp2): Test HAVE_EXP2 instead of HAVE_DECL_EXP2.
(exp2l): Test HAVE_EXP2L instead of HAVE_DECL_EXP2L.
(expm1l): Test HAVE_EXPM1L instead of HAVE_DECL_EXPM1L.
(log2f): Test HAVE_LOG2F instead of HAVE_DECL_LOG2F.
(log2): Test HAVE_LOG2 instead of HAVE_DECL_LOG2.
(log2l): Test HAVE_LOG2L instead of HAVE_DECL_LOG2L.
(remainder): Don't test HAVE_DECL_REMAINDER.
(remainderl): Test HAVE_REMAINDERL instead of HAVE_DECL_REMAINDERL.
(rintf): Test HAVE_RINTF instead of HAVE_DECL_RINTF.
(roundf): Test HAVE_ROUNDF instead of HAVE_DECL_ROUNDF.
(round): Test HAVE_ROUND instead of HAVE_DECL_ROUND.
(roundl): Test HAVE_ROUNDL instead of HAVE_DECL_ROUNDL.
(isnanf, isnand): Remove code for IRIX.
* m4/math_h.m4 (gl_MATH_H_DEFAULTS): Initialize HAVE_COPYSIGNF,
HAVE_EXP2, HAVE_EXP2F, HAVE_EXP2L, HAVE_EXPM1L, HAVE_LOG2, HAVE_LOG2F,
HAVE_LOG2L, HAVE_REMAINDERL, HAVE_RINTF, HAVE_ROUND, HAVE_ROUNDF,
HAVE_ROUNDL. Don't initialize HAVE_DECL_CBRTF, HAVE_DECL_CBRTL,
HAVE_DECL_COPYSIGNF, HAVE_DECL_EXP2, HAVE_DECL_EXP2F, HAVE_DECL_EXP2L,
HAVE_DECL_EXPM1L, HAVE_DECL_LOG2, HAVE_DECL_LOG2F, HAVE_DECL_LOG2L,
HAVE_DECL_REMAINDER, HAVE_DECL_REMAINDERL, HAVE_DECL_RINTF,
HAVE_DECL_ROUND, HAVE_DECL_ROUNDF, HAVE_DECL_ROUNDL.
* modules/math-h (Makefile.am): Substitute HAVE_COPYSIGNF, HAVE_EXP2,
HAVE_EXP2F, HAVE_EXP2L, HAVE_EXPM1L, HAVE_LOG2, HAVE_LOG2F, HAVE_LOG2L,
HAVE_REMAINDERL, HAVE_RINTF, HAVE_ROUND, HAVE_ROUNDF, HAVE_ROUNDL.
Don't substitute HAVE_DECL_CBRTF, HAVE_DECL_CBRTL, HAVE_DECL_COPYSIGNF,
HAVE_DECL_EXP2, HAVE_DECL_EXP2F, HAVE_DECL_EXP2L, HAVE_DECL_EXPM1L,
HAVE_DECL_LOG2, HAVE_DECL_LOG2F, HAVE_DECL_LOG2L, HAVE_DECL_REMAINDER,
HAVE_DECL_REMAINDERL, HAVE_DECL_RINTF, HAVE_DECL_ROUND,
HAVE_DECL_ROUNDF, HAVE_DECL_ROUNDL.
* m4/cbrtf.m4 (gl_FUNC_CBRTF_WORKS): Remove macro.
(gl_FUNC_CBRTF): Don't invoke it. Don't set HAVE_DECL_CBRTF.
* m4/cbrtl.m4 (gl_FUNC_CBRTL): Don't set HAVE_DECL_CBRTL. Remove test
regarding cbrtl (-0.0L).
* lib/cbrtl.c (cbrtl): Remove code for IRIX.
* m4/copysignf.m4 (gl_FUNC_COPYSIGNF): Don't set HAVE_DECL_COPYSIGNF.
* m4/exp2f.m4 (gl_FUNC_EXP2F): Don't set HAVE_DECL_EXP2F.
* m4/exp2.m4 (gl_FUNC_EXP2): Don't set HAVE_DECL_EXP2.
* m4/exp2l.m4 (gl_FUNC_EXP2L): Don't set HAVE_DECL_EXP2L. Remove code
for IRIX. Remove test regarding exp2l (-Inf).
* m4/expm1l.m4 (gl_FUNC_EXPM1L): Don't set HAVE_DECL_EXPM1L. Remove code
for IRIX.
* m4/log2f.m4 (gl_FUNC_LOG2F): Don't set HAVE_DECL_LOG2F.
* m4/log2.m4 (gl_FUNC_LOG2): Don't set HAVE_DECL_LOG2.
* lib/log2.c (log2): Remove code for IRIX.
* m4/log2l.m4 (gl_FUNC_LOG2L): Don't set HAVE_DECL_LOG2L. Remove code
for IRIX.
* lib/log2l.c (log2l): Remove code for IRIX.
* m4/remainder.m4 (gl_FUNC_REMAINDER): Don't set HAVE_DECL_REMAINDER.
* m4/remainderl.m4 (gl_FUNC_REMAINDERL): Don't set HAVE_DECL_REMAINDERL.
Remove code for IRIX.
* m4/rintf.m4 (gl_FUNC_RINTF): Don't set HAVE_DECL_RINTF.
* m4/roundf.m4 (gl_FUNC_ROUNDF): Don't set HAVE_DECL_ROUNDF.
* m4/round.m4 (gl_FUNC_ROUND): Don't set HAVE_DECL_ROUND.
* m4/roundl.m4 (gl_FUNC_ROUNDL): Don't set HAVE_DECL_ROUNDL.

Download

m4/remainderl.m4

# remainderl.m4
# serial 19
dnl Copyright (C) 2012-2025 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl This file is offered as-is, without any warranty.

AC_DEFUN([gl_FUNC_REMAINDERL],
[
  m4_divert_text([DEFAULTS], [gl_remainderl_required=plain])
  AC_REQUIRE([gl_MATH_H_DEFAULTS])
  AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  AC_REQUIRE([gl_FUNC_REMAINDER])

  dnl Persuade glibc <math.h> to declare remainderl().
  AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])

  dnl Test whether remainderl() exists. Assume that remainderl(), if it exists, is
  dnl defined in the same library as remainder().
  saved_LIBS="$LIBS"
  LIBS="$LIBS $REMAINDER_LIBM"
  AC_CACHE_CHECK([for remainderl],
    [gl_cv_func_remainderl],
    [
      AC_LINK_IFELSE(
        [AC_LANG_PROGRAM(
           [[#ifndef __NO_MATH_INLINES
             # define __NO_MATH_INLINES 1 /* for glibc */
             #endif
             #include <math.h>
             extern
             #ifdef __cplusplus
             "C"
             #endif
             long double remainderl (long double, long double);
             long double (*funcptr) (long double, long double) = remainderl;
             long double x;
             long double y;]],
           [[return funcptr (x, y) > 1
                    || remainderl (x, y) > 1;]])],
        [gl_cv_func_remainderl=yes],
        [gl_cv_func_remainderl=no])
    ])
  LIBS="$saved_LIBS"
  if test $gl_cv_func_remainderl = yes; then
    HAVE_REMAINDERL=1
    REMAINDERL_LIBM="$REMAINDER_LIBM"

    saved_LIBS="$LIBS"
    LIBS="$LIBS $REMAINDERL_LIBM"
    gl_FUNC_REMAINDERL_WORKS
    LIBS="$saved_LIBS"
    case "$gl_cv_func_remainderl_works" in
      *yes) ;;
      *) REPLACE_REMAINDERL=1 ;;
    esac
  else
    HAVE_REMAINDERL=0
  fi
  if test $HAVE_REMAINDERL = 0 || test $REPLACE_REMAINDERL = 1; then
    dnl Find libraries needed to link lib/remainderl.c.
    if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
      REMAINDERL_LIBM="$REMAINDER_LIBM"
    else
      AC_REQUIRE([gl_FUNC_FABSL])
      AC_REQUIRE([gl_FUNC_FMODL])
      AC_REQUIRE([gl_FUNC_ISNANL])
      REMAINDERL_LIBM=
      dnl Append $FABSL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
      case " $REMAINDERL_LIBM " in
        *" $FABSL_LIBM "*) ;;
        *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FABSL_LIBM" ;;
      esac
      dnl Append $FMODL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
      case " $REMAINDERL_LIBM " in
        *" $FMODL_LIBM "*) ;;
        *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FMODL_LIBM" ;;
      esac
      dnl Append $ISNANL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
      case " $REMAINDERL_LIBM " in
        *" $ISNANL_LIBM "*) ;;
        *) REMAINDERL_LIBM="$REMAINDERL_LIBM $ISNANL_LIBM" ;;
      esac
    fi
  fi
  AC_SUBST([REMAINDERL_LIBM])
])

dnl Test whether remainderl() works.
dnl It produces completely wrong values on OpenBSD 5.1/SPARC.
dnl On musl 1.2.2/{arm64,s390x} and NetBSD 10.0, the result is accurate to only
dnl 16 digits.
AC_DEFUN([gl_FUNC_REMAINDERL_WORKS],
[
  AC_REQUIRE([AC_PROG_CC])
  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  AC_CACHE_CHECK([whether remainderl works], [gl_cv_func_remainderl_works],
    [
      AC_RUN_IFELSE(
        [AC_LANG_SOURCE([[
#ifndef __NO_MATH_INLINES
# define __NO_MATH_INLINES 1 /* for glibc */
#endif
#include <float.h>
#include <math.h>
/* Override the values of <float.h>, like done in float.in.h.  */
#if defined __i386__ && (defined __BEOS__ || defined __OpenBSD__)
# undef LDBL_MANT_DIG
# define LDBL_MANT_DIG   64
# undef LDBL_MIN_EXP
# define LDBL_MIN_EXP    (-16381)
# undef LDBL_MAX_EXP
# define LDBL_MAX_EXP    16384
#endif
#if defined __i386__ && (defined __FreeBSD__ || defined __DragonFly__)
# undef LDBL_MANT_DIG
# define LDBL_MANT_DIG   64
# undef LDBL_MIN_EXP
# define LDBL_MIN_EXP    (-16381)
# undef LDBL_MAX_EXP
# define LDBL_MAX_EXP    16384
#endif
#if (defined _ARCH_PPC || defined _POWER) && defined _AIX && (LDBL_MANT_DIG == 106) && defined __GNUC__
# undef LDBL_MIN_EXP
# define LDBL_MIN_EXP DBL_MIN_EXP
#endif
extern
#ifdef __cplusplus
"C"
#endif
long double remainderl (long double, long double);
static long double dummy (long double x, long double y) { return 0; }
volatile long double gx;
volatile long double gy;
long double gz;
int main (int argc, char *argv[])
{
  long double (* volatile my_remainderl) (long double, long double) =
    argc ? remainderl : dummy;
  int result = 0;
  /* This test fails on OpenBSD 5.1/SPARC.  */
  {
    gx = 9.245907126L;
    gy = 3.141592654L;
    gz = remainderl (gx, gy);
    if (gz >= 0.0L)
      result |= 1;
  }
  /* This test fails on musl 1.2.2/arm64, musl 1.2.2/s390x, NetBSD 10.0.  */
  {
    const long double TWO_LDBL_MANT_DIG = /* 2^LDBL_MANT_DIG */
      (long double) (1U << ((LDBL_MANT_DIG - 1) / 5))
      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 1) / 5))
      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 2) / 5))
      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 3) / 5))
      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 4) / 5));
    long double x = 11.357996098166760874793827872740874983168L;
    long double y = 0.486497838502717923110029188864352615388L;
    long double z = my_remainderl (x, y) - (x - 23 * y);
    long double err = z * TWO_LDBL_MANT_DIG;
    if (!(err >= -32.0L && err <= 32.0L))
      result |= 2;
  }
  return result;
}
]])],
        [gl_cv_func_remainderl_works=yes],
        [gl_cv_func_remainderl_works=no],
        [case "$host_os" in
                               # Guess yes on glibc systems.
           *-gnu* | gnu*)      gl_cv_func_remainderl_works="guessing yes" ;;
                               # Guess no on musl systems.
           *-musl* | midipix*) gl_cv_func_remainderl_works="guessing no" ;;
                               # Guess no on NetBSD and OpenBSD.
           netbsd* | openbsd*) gl_cv_func_remainderl_works="guessing no" ;;
                               # Guess yes on native Windows.
           mingw* | windows*)  gl_cv_func_remainderl_works="guessing yes" ;;
                               # If we don't know, obey --enable-cross-guesses.
           *)                  gl_cv_func_remainderl_works="$gl_cross_guess_normal" ;;
         esac
        ])
    ])
])

Download

kc3-lang/gnulib/m4/remainderl.m4

Commit

m4/remainderl.m4