kc3-lang/harfbuzz/win32/create-lists.bat

• Show log

  Commit

• Hash : d7b6636e
  Author :
  Date : 2015-11-03T19:00:42
  

  build: Support Visual Studio builds using NMake
  
  This adds a set of NMake Makefiles that can be used to build HarfBuzz, from
  the standard basic build building the minimal HarfBuzz DLL (consisting
  of OpenType, fallback and Uniscribe support only), to a full fledged build
  consisting of GLib and FreeType support, as well as building the utilities,
  the test programs in src/ and test/api, and HarfBuzz-ICU and
  HarfBuzz-GObject, and up to building the introspection files.  This means a
  flexible build mechanism is supported here, so anything that is supported
  for a Windows build (code-wise), should all be supported by this build
  system.
  
  As in an earlier commit, the source listings are shared with the autotools
  builds with the various Makefile.sources in src/, src/hb-ucdn and util/, and
  this set of NMake Makefiles will transform these lists into the form they
  want.
  
  In the current form, all the test programs in test/api pass, and this has
  been checked successfully with 'make -j8 distcheck'.
  

Download

• win32/create-lists.bat

• @echo off
  rem Simple .bat script for creating the NMake Makefile snippets.
  
  if not "%1" == "header" if not "%1" == "file" if not "%1" == "footer" goto :error_cmd
  if "%2" == "" goto error_no_destfile
  
  if "%1" == "header" goto :header
  if "%1" == "file" goto :addfile
  if "%1" == "footer" goto :footer
  
  :header
  if "%3" == "" goto error_var
  echo %3 =	\>>%2
  goto done
  
  :addfile
  if "%3" == "" goto error_file
  echo.	%3	\>>%2
  goto done
  
  :footer
  echo.	$(NULL)>>%2
  echo.>>%2
  goto done
  
  :error_cmd
  echo Specified command '%1' was invalid.  Valid commands are: header file footer.
  goto done
  
  :error_no_destfile
  echo Destination NMake snippet file must be specified
  goto done
  
  :error_var
  echo A name must be specified for using '%1'.
  goto done
  
  :error_file
  echo A file must be specified for using '%1'.
  goto done
  
  :done

Download