kc3-lang/libbsd/m4/libbsd-linker.m4

Branch - branch -mainmasterv0.11origin/HEADorigin/main- tag -0.9.10.9.00.8.70.8.60.8.50.8.40.8.30.8.20.8.10.8.00.7.00.6.00.5.20.5.10.5.00.4.20.4.10.4.00.3.00.2.00.11.70.11.60.11.50.11.40.11.30.11.20.11.10.11.00.10.00.1.60.1.50.1.40.1.30.1.20.1.10.1.00.0.10.0

• Show log

  Commit

• Hash : 30b48ed9
  Author :
  Date : 2023-05-26T23:50:10
  

  build: Refactor linker script detection into a new m4 function

Download

• m4/libbsd-linker.m4

• # Copyright © 2019, 2022 Guillem Jover <guillem@hadrons.org>
  
  # LIBBSD_LINKER_VERSION_SCRIPT
  # ----------------------------
  AC_DEFUN([LIBBSD_LINKER_VERSION_SCRIPT], [
    AC_CACHE_CHECK([if ld supports --version-script flag],
      [libbsd_cv_version_script], [
      echo "{ global: symbol; local: *; };" >conftest.map
      save_LDFLAGS=$LDFLAGS
      LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
      AC_LINK_IFELSE([
        AC_LANG_PROGRAM([[
  extern int symbol(void);
  int symbol(void) { return 0; }
  ]], [[
  ]])
      ], [
        libbsd_cv_version_script=yes
      ], [
        libbsd_cv_version_script=no
      ])
      LDFLAGS="$save_LDFLAGS"
      rm -f conftest.map
    ])
    AM_CONDITIONAL([HAVE_LINKER_VERSION_SCRIPT],
      [test "x$libbsd_cv_version_script" = "xyes"])
  ])
  

Download