CheckConstExists.cmake

Branch :

Show log
Commit
Author : Azat Khuzhin
Date : 2018-10-18 23:16:05
Hash : 4c61a04c
Message : Make cmake's check_const_exists() rely on cache

cmake/CheckConstExists.cmake

include(CheckCSourceCompiles)

macro(check_const_exists CONST FILES VARIABLE)
  if (NOT DEFINED ${VARIABLE})
    set(check_const_exists_source "")
    foreach(file ${FILES})
      set(check_const_exists_source
          "${check_const_exists_source}
          #include <${file}>")
    endforeach()
    set(check_const_exists_source
        "${check_const_exists_source}
        int main() { (void)${CONST}; return 0; }")

    check_c_source_compiles("${check_const_exists_source}" ${VARIABLE})

    if (${${VARIABLE}})
      set(${VARIABLE} 1 CACHE INTERNAL "Have const ${CONST}")
      message(STATUS "Looking for ${CONST} - found")
    else()
      set(${VARIABLE} 0 CACHE INTERNAL "Have const ${CONST}")
      message(STATUS "Looking for ${CONST} - not found")
    endif()
  endif()
endmacro(check_const_exists)

kc3-lang/libevent/cmake/CheckConstExists.cmake

Commit

kc3-lang/libevent /cmake/CheckConstExists.cmake