kc3-lang/libffi/m4/asmcfi.m4

• Show log

  Commit

• Hash : 854ce7be
  Author :
  Date : 2025-06-02T20:18:46
  

  Make 3.5.0-pre0 release. Build and publish Windows binaries. Clean up testing. (#912)
  
  This commit removes many platforms from the testing workflow.
  They will be added back in future commits.

Download

• m4/asmcfi.m4

• dnl ------------------------------------------------------------------
  dnl  Check whether the assembler understands .cfi_* pseudo-ops.
  dnl ------------------------------------------------------------------
  AC_DEFUN([GCC_AS_CFI_PSEUDO_OP],
  [
    AC_CACHE_CHECK([assembler .cfi pseudo-op support],
                   [gcc_cv_as_cfi_pseudo_op],
    [ AC_LANG_PUSH([C])
      AC_COMPILE_IFELSE(
        [AC_LANG_SOURCE([[
          #ifdef _MSC_VER
          Nope.
          #endif
          int foo (void)
          {
            __asm__ (".cfi_remember_state\n\t"
                     ".cfi_restore_state\n\t");
            return 0;
          }
        ]])],
        [gcc_cv_as_cfi_pseudo_op=yes],
        [gcc_cv_as_cfi_pseudo_op=no])
      AC_LANG_POP([C])
    ])
  
    if test "x$gcc_cv_as_cfi_pseudo_op" = xyes; then
      AC_DEFINE([HAVE_AS_CFI_PSEUDO_OP], [1],
                [Define if your assembler supports .cfi_* directives.])
    fi
  ])
  

Download