kc3-lang/libjpeg-turbo/sharedlib/CMakeLists.txt

• Show log

  Commit

• Hash : 27d4c5ea
  Author :
  Date : 2016-11-23T17:12:57
  

  Build: Fix RPATH handling
  
  CMAKE_INSTALL_RPATH has to be set before the targets are defined (oops.)
  
  This also explicitly turns on MACOSX_RPATH for the shared libraries
  (which is the default with newer versions of CMake but not with 2.8.x.)
  The old autotools/libtool build system hard-coded the install name
  directory of the OS X shared libraries to libdir, which meant that any
  executable that linked against those libraries would also be hard-coded
  to look for the libjpeg-turbo libraries in that directory.  @rpath makes
  the OS X version of libjpeg-turbo behave like the Linux version, in the
  sense that the executables under /opt/libjpeg-turbo/bin will
  automatically pick up the libraries under /opt/libjpeg-turbo/lib* by
  default, but other executables won't unless they are linked with -rpath.
  

Download

• sharedlib/CMakeLists.txt

• # Anything that must be linked against the shared C library on Windows must
  # be built in this subdirectory, because CMake doesn't allow us to override
  # the compiler flags for each build type except at directory scope.  Note
  # to CMake developers:  Add a COMPILE_FLAGS_<CONFIG> target property, or
  # better yet, provide a friendly way of configuring a Windows target to use the
  # static C library.
  
  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
  set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
  set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
  
  if(MSVC)
    # Build all configurations against shared C library
    foreach(var CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
      CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
      if(${var} MATCHES "/MT")
        string(REGEX REPLACE "/MT" "/MD" ${var} "${${var}}")
      endif()
    endforeach()
  endif()
  
  foreach(src ${JPEG_SOURCES})
    set(JPEG_SRCS ${JPEG_SRCS} ${CMAKE_SOURCE_DIR}/${src})
  endforeach()
  
  if(WITH_SIMD AND MSVC_IDE)
    # This tells CMake that the "source" files haven't been generated yet
    set_source_files_properties(${SIMD_OBJS} PROPERTIES GENERATED 1)
  endif()
  
  if(WIN32)
    if(WITH_MEM_SRCDST)
      set(DEFFILE ${CMAKE_SOURCE_DIR}/win/jpeg${SO_MAJOR_VERSION}-memsrcdst.def)
    else()
      set(DEFFILE ${CMAKE_SOURCE_DIR}/win/jpeg${SO_MAJOR_VERSION}.def)
    endif()
  endif()
  add_library(jpeg SHARED ${JPEG_SRCS} ${DEFFILE} $<TARGET_OBJECTS:simd>
    ${SIMD_OBJS})
  
  set_target_properties(jpeg PROPERTIES SOVERSION ${SO_MAJOR_VERSION}
    VERSION ${SO_MAJOR_VERSION}.${SO_AGE}.${SO_MINOR_VERSION})
  if(APPLE)
    set_target_properties(jpeg PROPERTIES MACOSX_RPATH 1)
  endif()
  if(MAPFLAG)
    set_target_properties(jpeg PROPERTIES
      LINK_FLAGS "${MAPFLAG}${CMAKE_BINARY_DIR}/libjpeg.map")
  endif()
  if(MSVC)
    set_target_properties(jpeg PROPERTIES SUFFIX ${SO_MAJOR_VERSION}.dll)
    # The jsimd_*.c file is built using /MT, so this prevents a linker warning.
    set_target_properties(jpeg PROPERTIES LINK_FLAGS "/NODEFAULTLIB:LIBCMT /NODEFAULTLIB:LIBCMTD")
  elseif(MINGW)
    set_target_properties(jpeg PROPERTIES SUFFIX -${SO_MAJOR_VERSION}.dll)
  endif()
  
  if(WIN32)
    set(USE_SETMODE "-DUSE_SETMODE")
  endif()
  if(WITH_12BIT)
    set(COMPILE_FLAGS "-DGIF_SUPPORTED -DPPM_SUPPORTED ${USE_SETMODE}")
  else()
    set(COMPILE_FLAGS "-DBMP_SUPPORTED -DGIF_SUPPORTED -DPPM_SUPPORTED -DTARGA_SUPPORTED ${USE_SETMODE}")
  	set(CJPEG_BMP_SOURCES ../rdbmp.c ../rdtarga.c)
  	set(DJPEG_BMP_SOURCES ../wrbmp.c ../wrtarga.c)
  endif()
  
  add_executable(cjpeg ../cjpeg.c ../cdjpeg.c ../rdgif.c ../rdppm.c
    ../rdswitch.c ${CJPEG_BMP_SOURCES})
  set_property(TARGET cjpeg PROPERTY COMPILE_FLAGS ${COMPILE_FLAGS})
  target_link_libraries(cjpeg jpeg)
  
  add_executable(djpeg ../djpeg.c ../cdjpeg.c ../rdcolmap.c ../rdswitch.c
    ../wrgif.c ../wrppm.c ${DJPEG_BMP_SOURCES})
  set_property(TARGET djpeg PROPERTY COMPILE_FLAGS ${COMPILE_FLAGS})
  target_link_libraries(djpeg jpeg)
  
  add_executable(jpegtran ../jpegtran.c ../cdjpeg.c ../rdswitch.c ../transupp.c)
  target_link_libraries(jpegtran jpeg)
  set_property(TARGET jpegtran PROPERTY COMPILE_FLAGS "${USE_SETMODE}")
  
  add_executable(jcstest ../jcstest.c)
  target_link_libraries(jcstest jpeg)
  
  install(TARGETS jpeg cjpeg djpeg jpegtran
    ARCHIVE DESTINATION ${LIBDIR}
    LIBRARY DESTINATION ${LIBDIR}
    RUNTIME DESTINATION ${BINDIR})
  

Download