kc3-lang/libjpeg-turbo/sharedlib/CMakeLists.txt

• Show log

  Commit

• Hash : 19c791cd
  Author :
  Date : 2018-03-08T10:55:20
  

  Improve code formatting consistency
  
  With rare exceptions ...
  - Always separate line continuation characters by one space from
    preceding code.
  - Always use two-space indentation.  Never use tabs.
  - Always use K&R-style conditional blocks.
  - Always surround operators with spaces, except in raw assembly code.
  - Always put a space after, but not before, a comma.
  - Never put a space between type casts and variables/function calls.
  - Never put a space between the function name and the argument list in
    function declarations and prototypes.
  - Always surround braces ('{' and '}') with spaces.
  - Always surround statements (if, for, else, catch, while, do, switch)
    with spaces.
  - Always attach pointer symbols ('*' and '**') to the variable or
    function name.
  - Always precede pointer symbols ('*' and '**') by a space in type
    casts.
  - Use the MIN() macro from jpegint.h within the libjpeg and TurboJPEG
    API libraries (using min() from tjutil.h is still necessary for
    TJBench.)
  - Where it makes sense (particularly in the TurboJPEG code), put a blank
    line after variable declaration blocks.
  - Always separate statements in one-liners by two spaces.
  
  The purpose of this was to ease maintenance on my part and also to make
  it easier for contributors to figure out how to format patch
  submissions.  This was admittedly confusing (even to me sometimes) when
  we had 3 or 4 different style conventions in the same source tree.  The
  new convention is more consistent with the formatting of other OSS code
  bases.
  
  This commit corrects deviations from the chosen formatting style in the
  libjpeg API code and reformats the TurboJPEG API code such that it
  conforms to the same standard.
  
  NOTES:
  - Although it is no longer necessary for the function name in function
    declarations to begin in Column 1 (this was historically necessary
    because of the ansi2knr utility, which allowed libjpeg to be built
    with non-ANSI compilers), we retain that formatting for the libjpeg
    code because it improves readability when using libjpeg's function
    attribute macros (GLOBAL(), etc.)
  - This reformatting project was accomplished with the help of AStyle and
    Uncrustify, although neither was completely up to the task, and thus
    a great deal of manual tweaking was required.  Note to developers of
    code formatting utilities:  the libjpeg-turbo code base is an
    excellent test bed, because AFAICT, it breaks every single one of the
    utilities that are currently available.
  - The legacy (MMX, SSE, 3DNow!) assembly code for i386 has been
    formatted to match the SSE2 code (refer to
    ff5685d5344273df321eb63a005eaae19d2496e3.)  I hadn't intended to
    bother with this, but the Loongson MMI implementation demonstrated
    that there is still academic value to the MMX implementation, as an
    algorithmic model for other 64-bit vector implementations.  Thus, it
    is desirable to improve its readability in the same manner as that of
    the SSE2 implementation.
  

Download

• sharedlib/CMakeLists.txt

• # Anything that must be linked against the shared C library on Windows must
  # be built in this subdirectory, because CMake doesn't allow us to override
  # the compiler flags for each build type except at directory scope.  Note
  # to CMake developers:  Add a COMPILE_FLAGS_<CONFIG> target property, or
  # better yet, provide a friendly way of configuring a Windows target to use the
  # static C library.
  
  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/..)
  set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/..)
  set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/..)
  
  if(MSVC)
    # Build all configurations against shared C library
    foreach(var CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
      CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
      if(${var} MATCHES "/MT")
        string(REGEX REPLACE "/MT" "/MD" ${var} "${${var}}")
      endif()
    endforeach()
  endif()
  
  foreach(src ${JPEG_SOURCES})
    set(JPEG_SRCS ${JPEG_SRCS} ../${src})
  endforeach()
  
  if(WITH_SIMD AND MSVC_IDE)
    # This tells CMake that the "source" files haven't been generated yet
    set_source_files_properties(${SIMD_OBJS} PROPERTIES GENERATED 1)
  endif()
  
  if(WIN32)
    if(WITH_MEM_SRCDST)
      set(DEFFILE ../win/jpeg${SO_MAJOR_VERSION}-memsrcdst.def)
    else()
      set(DEFFILE ../win/jpeg${SO_MAJOR_VERSION}.def)
    endif()
  endif()
  add_library(jpeg SHARED ${JPEG_SRCS} ${DEFFILE} $<TARGET_OBJECTS:simd>
    ${SIMD_OBJS})
  
  set_target_properties(jpeg PROPERTIES SOVERSION ${SO_MAJOR_VERSION}
    VERSION ${SO_MAJOR_VERSION}.${SO_AGE}.${SO_MINOR_VERSION})
  if(APPLE)
    set_target_properties(jpeg PROPERTIES MACOSX_RPATH 1)
  endif()
  if(MAPFLAG)
    set_target_properties(jpeg PROPERTIES
      LINK_FLAGS "${MAPFLAG}${CMAKE_CURRENT_BINARY_DIR}/../libjpeg.map")
  endif()
  if(MSVC)
    set_target_properties(jpeg PROPERTIES SUFFIX ${SO_MAJOR_VERSION}.dll)
    # The jsimd_*.c file is built using /MT, so this prevents a linker warning.
    set_target_properties(jpeg PROPERTIES LINK_FLAGS "/NODEFAULTLIB:LIBCMT /NODEFAULTLIB:LIBCMTD")
  elseif(MINGW)
    set_target_properties(jpeg PROPERTIES SUFFIX -${SO_MAJOR_VERSION}.dll)
  endif()
  
  if(WIN32)
    set(USE_SETMODE "-DUSE_SETMODE")
  endif()
  if(WITH_12BIT)
    set(COMPILE_FLAGS "-DGIF_SUPPORTED -DPPM_SUPPORTED ${USE_SETMODE}")
  else()
    set(COMPILE_FLAGS "-DBMP_SUPPORTED -DGIF_SUPPORTED -DPPM_SUPPORTED -DTARGA_SUPPORTED ${USE_SETMODE}")
    set(CJPEG_BMP_SOURCES ../rdbmp.c ../rdtarga.c)
    set(DJPEG_BMP_SOURCES ../wrbmp.c ../wrtarga.c)
  endif()
  
  add_executable(cjpeg ../cjpeg.c ../cdjpeg.c ../rdgif.c ../rdppm.c
    ../rdswitch.c ${CJPEG_BMP_SOURCES})
  set_property(TARGET cjpeg PROPERTY COMPILE_FLAGS ${COMPILE_FLAGS})
  target_link_libraries(cjpeg jpeg)
  
  add_executable(djpeg ../djpeg.c ../cdjpeg.c ../rdcolmap.c ../rdswitch.c
    ../wrgif.c ../wrppm.c ${DJPEG_BMP_SOURCES})
  set_property(TARGET djpeg PROPERTY COMPILE_FLAGS ${COMPILE_FLAGS})
  target_link_libraries(djpeg jpeg)
  
  add_executable(jpegtran ../jpegtran.c ../cdjpeg.c ../rdswitch.c ../transupp.c)
  target_link_libraries(jpegtran jpeg)
  set_property(TARGET jpegtran PROPERTY COMPILE_FLAGS "${USE_SETMODE}")
  
  add_executable(jcstest ../jcstest.c)
  target_link_libraries(jcstest jpeg)
  
  install(TARGETS jpeg cjpeg djpeg jpegtran
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  

Download