kc3-lang/md4c/src/CMakeLists.txt

• Show log

  Commit

• Hash : 2b6ebdfa
  Author :
  Date : 2021-01-09T11:54:27
  

  Fix use of the cmake package (#146)
  
  Fix use of the cmake package
  
  Fix use of the cmake package and its imported targets.
  Make sure that the include dir comes with the cmake targets
  Put everything under md4cConfig so that the md4c-html can see
  md4c.
  Use md4c namespace so that the targets become md4c::md4c and
  md4c::md4c-html following cmake standards for imported targets.
  
  Fixes #145.

Download

• src/CMakeLists.txt

• 
  set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS 1)
  set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DDEBUG")
  
  
  # Build rules for MD4C parser library
  
  configure_file(md4c.pc.in md4c.pc @ONLY)
  add_library(md4c md4c.c md4c.h)
  if(CMAKE_C_COMPILER_ID MATCHES "Clang|GNU")
      target_compile_options(md4c PRIVATE -Wall -Wextra)
  endif()
  set_target_properties(md4c PROPERTIES
      COMPILE_FLAGS "-DMD4C_USE_UTF8"
      VERSION ${MD_VERSION}
      SOVERSION ${MD_VERSION_MAJOR}
      PUBLIC_HEADER md4c.h
  )
  
  # Build rules for HTML renderer library
  
  configure_file(md4c-html.pc.in md4c-html.pc @ONLY)
  add_library(md4c-html md4c-html.c md4c-html.h entity.c entity.h)
  set_target_properties(md4c-html PROPERTIES
      VERSION ${MD_VERSION}
      SOVERSION ${MD_VERSION_MAJOR}
      PUBLIC_HEADER md4c-html.h
  )
  target_link_libraries(md4c-html md4c)
  
  
  # Install rules
  
  install(
      TARGETS md4c
      EXPORT md4cConfig
      ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
      LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
      RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
      PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
      INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
  )
  install(FILES ${CMAKE_BINARY_DIR}/src/md4c.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
  
  install(
      TARGETS md4c-html
      EXPORT md4cConfig
      ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
      LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
      RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
      PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
  )
  install(FILES ${CMAKE_BINARY_DIR}/src/md4c-html.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
  
  install(EXPORT md4cConfig DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/md4c/ NAMESPACE md4c::)
  
  

Download