kmx.io/prism.js/examples/prism-antlr4.html

• Show log

  Commit

• Hash : 0b539136
  Author :
  Date : 2020-01-06T14:39:45
  

  Added checks for examples (#2128) This adds a check to `premerge` to detect missing and lone examples. All currently missing examples were added with some exceptions.

Download

• examples/prism-antlr4.html

• <h2>Full example</h2>
  <pre><code>// Source: https://github.com/antlr/grammars-v4/blob/master/json/JSON.g4
  
  /** Taken from "The Definitive ANTLR 4 Reference" by Terence Parr */
  
  // Derived from http://json.org
  grammar JSON;
  
  json
     : value
     ;
  
  obj
     : '{' pair (',' pair)* '}'
     | '{' '}'
     ;
  
  pair
     : STRING ':' value
     ;
  
  array
     : '[' value (',' value)* ']'
     | '[' ']'
     ;
  
  value
     : STRING
     | NUMBER
     | obj
     | array
     | 'true'
     | 'false'
     | 'null'
     ;
  
  
  STRING
     : '"' (ESC | SAFECODEPOINT)* '"'
     ;
  
  
  fragment ESC
     : '\\' (["\\/bfnrt] | UNICODE)
     ;
  fragment UNICODE
     : 'u' HEX HEX HEX HEX
     ;
  fragment HEX
     : [0-9a-fA-F]
     ;
  fragment SAFECODEPOINT
     : ~ ["\\\u0000-\u001F]
     ;
  
  
  NUMBER
     : '-'? INT ('.' [0-9] +)? EXP?
     ;
  
  fragment INT
     : '0' | [1-9] [0-9]*
     ;
  
  // no leading zeros
  
  fragment EXP
     : [Ee] [+\-]? INT
     ;
  
  // \- since - means "range" inside [...]
  
  WS
     : [ \t\n\r] + -> skip
     ;</code></pre>
  

Download