thodg/libgit2/src/cli/CMakeLists.txt

• Show log

  Commit

• Hash : 3a3ab065
  Author :
  Date : 2020-05-03T23:13:28
  

  cli: infrastructure for a cli project
  
  Introduce a command-line interface for libgit2.  The goal is for it to
  be git-compatible.
  
  1. The libgit2 developers can more easily dogfood libgit2 to find bugs,
     and performance issues.
  
  2. There is growing usage of libgit2's examples as a client; libgit2's
     examples should be exactly that - simple code samples that illustrate
     libgit2's usage.  This satisfies that need directly.
  
  3. By producing a client ourselves, we can better understand the needs
     of client creators, possibly producing a shared "middleware" for
     commonly-used pieces of client functionality like interacting with
     external tools.
  
  4. Since git is the reference implementation, we may be able to benefit
     from git's unit tests, running their test suite against our CLI to
     ensure correct behavior.
  
  This commit introduces a simple infrastructure for the CLI.
  
  The CLI is currently links libgit2 statically; this is because the
  utility layer is required for libgit2 _but_ shares the error state
  handling with libgit2 itself.  There's no obviously good solution
  here without introducing annoying indirection or more complexity.
  Until we can untangle that dependency, this is a good step forward.
  
  In the meantime, we link the libgit2 object files, but we do not include
  the (private) libgit2 headers.  This constrains the CLI to the public
  libgit2 interfaces.
  

Download

• src/cli/CMakeLists.txt

• set(CLI_INCLUDES
  	"${libgit2_BINARY_DIR}/src"
  	"${libgit2_SOURCE_DIR}/src/util"
  	"${libgit2_SOURCE_DIR}/src/cli"
  	"${libgit2_SOURCE_DIR}/include")
  
  if(WIN32 AND NOT CYGWIN)
  	file(GLOB CLI_SRC_OS win32/*.c)
  	list(SORT CLI_SRC_OS)
  else()
  	file(GLOB CLI_SRC_OS unix/*.c)
  	list(SORT CLI_SRC_OS)
  endif()
  
  file(GLOB CLI_SRC_C *.c *.h)
  list(SORT CLI_SRC_C)
  
  #
  # The CLI currently needs to be statically linked against libgit2 because
  # the utility library uses libgit2's thread-local error buffers.  TODO:
  # remove this dependency and allow us to dynamically link against libgit2.
  #
  
  if(BUILD_CLI STREQUAL "dynamic")
  	set(CLI_LIBGIT2_LIBRARY libgit2package)
  else()
  	set(CLI_LIBGIT2_OBJECTS $<TARGET_OBJECTS:libgit2>)
  endif()
  
  #
  # Compile and link the CLI
  #
  
  add_executable(git2_cli ${CLI_SRC_C} ${CLI_SRC_OS} ${CLI_OBJECTS}
  	$<TARGET_OBJECTS:util>
  	${CLI_LIBGIT2_OBJECTS}
  	${LIBGIT2_DEPENDENCY_OBJECTS})
  target_link_libraries(git2_cli ${CLI_LIBGIT2_LIBRARY} ${LIBGIT2_SYSTEM_LIBS})
  
  set_target_properties(git2_cli PROPERTIES C_STANDARD 90)
  set_target_properties(git2_cli PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${libgit2_BINARY_DIR})
  
  ide_split_sources(git2_cli)
  
  target_include_directories(git2_cli PRIVATE ${CLI_INCLUDES})
  
  if(MSVC_IDE)
  	# Precompiled headers
  	set_target_properties(git2_cli PROPERTIES COMPILE_FLAGS "/Yuprecompiled.h /FIprecompiled.h")
  	set_source_files_properties(win32/precompiled.c COMPILE_FLAGS "/Ycprecompiled.h")
  endif()
  
  install(TARGETS git2_cli RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  

Download