remove-potcdate.sed

Branch :

Show log
Commit
Author : Bruno Haible
Date : 2024-12-15 13:11:29
Hash : deb432a1
Message : Use the newest gettext release. * po/Makefile.in.in: Upgrade to gettext-0.23, keeping the change 2019-01-27 Bruno Haible <bruno@clisp.org> Accommodate a shell that is not in /bin/sh. * po/Makefile.in.in (SHELL): Use the value found by configure. * po/*: Upgrade to gettext-0.23 as well.

po/remove-potcdate.sed

# Sed script that removes the POT-Creation-Date line in the header entry
# from a POT file.
#
# Copyright (C) 2002 Free Software Foundation, Inc.
# Copying and distribution of this file, with or without modification,
# are permitted in any medium without royalty provided the copyright
# notice and this notice are preserved.  This file is offered as-is,
# without any warranty.
#
# The distinction between the first and the following occurrences of the
# pattern is achieved by looking at the hold space.
/^"POT-Creation-Date: .*"$/{
x
# Test if the hold space is empty.
s/P/P/
ta
# Yes it was empty. First occurrence. Remove the line.
g
d
bb
:a
# The hold space was nonempty. Following occurrences. Do nothing.
x
:b
}

thodg/libiconv/po/remove-potcdate.sed

Commit

thodg/libiconv /po/remove-potcdate.sed