kc3-lang/libmd/m4/libmd-linker.m4

• Show log

  Commit

• Hash : b6be272e
  Author :
  Date : 2017-05-31T06:45:25
  

  build: Detect version script linker support at configure time This is not a widely supported feature, so only use if in case the linker does support it. Proposed-by: Michael Haubenwallner <michael.haubenwallner@ssi-schaefer.com>

Download

• m4/libmd-linker.m4

• # Copyright © 2014 Guillem Jover <guillem@hadrons.org>
  
  # LIBMD_LINKER_VERSION_SCRIPT
  # --------------------------
  AC_DEFUN([LIBMD_LINKER_VERSION_SCRIPT], [
    AC_CACHE_CHECK([for --version-script linker flag], [libmd_cv_version_script], [
      echo "{ global: symbol; local: *; };" >conftest.map
      save_LDFLAGS=$LDFLAGS
      LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
      AC_LINK_IFELSE([
        AC_LANG_PROGRAM([], [])
      ], [
        libmd_cv_version_script=yes
      ], [
        libmd_cv_version_script=no
      ])
      LDFLAGS="$save_LDFLAGS"
      rm -f conftest.map
    ])
    AM_CONDITIONAL([HAVE_LINKER_VERSION_SCRIPT],
      [test "x$libmd_cv_version_script" = "xyes"])
  ])
  

Download